# Jaké osoby studovaly na VŠE?

select ?osoba
where {
?osoba <http://cs.dbpedia.org/property/almaMater> <http://cs.dbpedia.org/resource/Vysoká_škola_ekonomická_v_Praze>.
}


# Jaké osoby studovaly na VŠE? (využití jmenných prostorů)

prefix cdbp: <http://cs.dbpedia.org/property/>
prefix cdbr: <http://cs.dbpedia.org/resource/>
select ?osoba
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze.
}

# Kolik osob z Wikipedie studovalo na VŠE? 132

prefix cdbp: <http://cs.dbpedia.org/property/>
prefix cdbr: <http://cs.dbpedia.org/resource/>
select count(?osoba) as ?pocet_osob
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze.
}


# Jaké osoby studovaly na VŠE a k jakým stranám se hlásí?
# a co Richard Hindls?

prefix cdbp: <http://cs.dbpedia.org/property/>
prefix cdbr: <http://cs.dbpedia.org/resource/>
select ?osoba ?strana
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze.
?osoba cdbp:strana ?strana.
}

# Jaké osoby studovaly na VŠE a k jakým stranám se hlásí (včetně neuvedených stran)?

prefix cdbp: <http://cs.dbpedia.org/property/>
prefix cdbr: <http://cs.dbpedia.org/resource/>
select ?osoba ?strana
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze.
optional {?osoba cdbp:strana ?strana.}
}

# Jaké osoby studovaly na VŠE a nemáme info o straně?

prefix cdbp: <http://cs.dbpedia.org/property/>
prefix cdbr: <http://cs.dbpedia.org/resource/>
select ?osoba
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze.
filter not exists{?osoba cdbp:strana ?strana.}
}

# Jaké osoby studovaly na VŠE a mají stranu uvedenou jen textově? (jiný typ negace; zkrácení trojic)

prefix cdbp: <http://cs.dbpedia.org/property/>
prefix cdbr: <http://cs.dbpedia.org/resource/>
select ?osoba ?strana
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze;
cdbp:strana ?strana.
filter (!(isURI(?strana)))
}

# Jaké osoby studovaly na VŠE a byly bezpartijní (část)?

prefix cdbp: <http://cs.dbpedia.org/property/>
prefix cdbr: <http://cs.dbpedia.org/resource/>
select ?osoba ?strana
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze;
cdbp:strana ?strana.
filter (!(isURI(?strana)) && strstarts(?strana,"bezpart") )
}

# Jaké osoby studovaly na VŠE a byly bezpartijní?

prefix cdbp: <http://cs.dbpedia.org/property/>
prefix cdbr: <http://cs.dbpedia.org/resource/>
select ?osoba ?strana
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze;
cdbp:strana ?strana.
filter (!(isURI(?strana)) && (strstarts(?strana,"bezpart") || strstarts(?strana,"nestr")))
}

# Z jakých stran jsou lidi z VŠE a kolik jich bylo?

prefix cdbp: <http://cs.dbpedia.org/property/>
prefix cdbr: <http://cs.dbpedia.org/resource/>
select ?strana
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze;
cdbp:strana ?strana.
}
group by ?strana

# Z jakých stran jsou lidi z VŠE a kolik jich bylo - v uspořádání?

prefix cdbp: <http://cs.dbpedia.org/property/>
prefix cdbr: <http://cs.dbpedia.org/resource/>
select ?strana count(?osoba) as ?pocet_osob
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze;
cdbp:strana ?strana.
}
group by ?strana
order by desc(?pocet_osob)

prefix cdbp: <http://cs.dbpedia.org/property/>
prefix cdbr: <http://cs.dbpedia.org/resource/>
select ?strana count(?osoba) as ?pocet_osob
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze;
cdbp:strana ?strana.
}
group by ?strana having (count(?osoba) >= 10)
order by desc(?pocet_osob)

prefix cdbp: <http://cs.dbpedia.org/property/>
prefix cdbr: <http://cs.dbpedia.org/resource/>
select ?osoba ?pozice
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze.
{
?osoba cdbp:strana ?pozice.
}
union
{
?osoba cdbp:úřad ?pozice.
}
}