# Jaké osoby studovaly na VŠE? (Míněno, takové, které jsou ve Wikipedii - takto i všude dále)

select ?osoba
where {
?osoba <http://cs.dbpedia.org/property/almaMater> <http://cs.dbpedia.org/resource/Vysoká_škola_ekonomická_v_Praze>.
}

# Jaké osoby studovaly na VŠE? (využití jmenných prostorů - takto i v dalších příkladech)

prefix cdbp: <http://cs.dbpedia.org/property/>
prefix cdbr: <http://cs.dbpedia.org/resource/>
select ?osoba
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze.
}

# Jaké osoby studovaly na VŠE? (včetně jména jako literálu)

select ?osoba ?jmeno
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze;
rdfs:label ?jmeno.
}

# Kolik osob studovalo na VŠE?

select count(?osoba) as ?pocet_osob
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze.
}

# Jaké osoby studovaly na VŠE a k jakým stranám se hlásí?

select ?osoba ?strana
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze.
?osoba cdbp:strana ?strana.
}

# Kolik lidí z VŠE bylo ve které straně nebo úřadu? (souhrnně - pozici?)

select ?osoba ?pozice
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze.
{
?osoba cdbp:strana ?pozice.
}
union
{
?osoba cdbp:úřad ?pozice.
}
}

# Totéž, ve zjednodušeném zápisu ("property paths")

select ?osoba ?pozice
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze;
cdbp:strana|cdbp:úřad ?pozice.
}

# Kterých 10 stran mělo nejvíce členů z VŠE?

select ?strana count(?osoba) as ?pocet_osob
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze;
cdbp:strana ?strana.
}
group by ?strana
order by desc(?pocet_osob)
limit 10

# Které strany měly alespoň 10 členů z VŠE?

select ?strana count(?osoba) as ?pocet_osob
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze;
cdbp:strana ?strana.
}
group by ?strana having (count(?osoba) >= 10)
order by desc(?pocet_osob)

# Jaké osoby studovaly na VŠE a k jakým stranám se hlásí (včetně neuvedených stran)?

select ?osoba ?strana
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze.
optional {?osoba cdbp:strana ?strana.}
}

# Jaké osoby studovaly na VŠE a nemáme info o straně?

select ?osoba
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze.
filter not exists{?osoba cdbp:strana ?strana.}
}

# Jaké osoby studovaly na VŠE a mají stranu uvedenou jen textově? 

select ?osoba ?strana
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze;
cdbp:strana ?strana.
filter (!(isIRI(?strana)))
}

# Které literálové názvy stran jsou jiného datového typu než xsd:string?

xsd: <http://www.w3.org/2001/XMLSchema#>
select distinct ?strana
where {
?osoba cdbp:strana ?strana.
filter(!(datatype(?strana) = xsd:string))
}

# Jaké osoby studovaly na VŠE a byly bezpartijní (část)?

select ?osoba ?strana
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze;
cdbp:strana ?strana.
filter (!(isIRI(?strana)) && strstarts(?strana,"bezpart") )
}

# Jaké osoby studovaly na VŠE a byly bezpartijní? (úplnější dotaz)

select ?osoba ?strana
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze;
cdbp:strana ?strana.
filter (!(isIRI(?strana)) && (strstarts(?strana,"bezpart") || strstarts(?strana,"nestr")))
}

% Explorační dotaz na všechny pojmenované grafy

select distinct ?g
where {
graph ?g {[] ?p [] . }
}

% Kolik který z grafů obsahuje trojic?

select distinct ?g count(*) as ?triples
where {
graph ?g {[] ?p []}
}
group by ?g
order by desc(?triples)


# Vytvořte graf, kde je uvedeno, kdo je v jaké straně s predikátem party z anglické DBpedia ontology, a jaký má osobní vzor (tj. předsedu strany)

prefix dbr: <http://dbpedia.org/ontology/>
prefix ex: <http://example.org/>

construct { ?osoba dbr:party ?strana ; ex:vzor ?predseda }
where {
?osoba cdbp:almaMater cdbr:Vysoká_škola_ekonomická_v_Praze;
cdbp:strana ?strana.
?strana cdbp:předseda ?predseda.
}